Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Compare Database
Option Explicit
'******
' Lecture/ecriture d'un fichier .txt, utilisé entre autre pour le déboguage de procédure
' v 1
'******
Private locRef As Variant
Private locCheminFichier As String
Property Let cheminFichier(chemin As String)
  locCheminFichier = chemin
End Property
Property Get cheminFichier() As String
  cheminFichier = locCheminFichier
End Property

Public Sub creer(Optional chemin As String = "")
On Error GoTo errInc
Dim ref As Variant
  'chemin complet du fichier de destination
  If Len(chemin) > 0 Then locCheminFichier = chemin
  'le chemin a été renseigné
  If Not Len(locCheminFichier) > 0 Then GoTo errChemin
  'on écrase le fichier s'il existe déjà
  If Dir(locCheminFichier) <> "" Then Kill locCheminFichier
  'ouverture du fichier
  locRef = FreeFile(1)
  Open locCheminFichier For Append Access Write Shared As locRef

fin:

  Exit Sub
errChemin:
  MsgBox "FichierTXT: impossible de créer le fichier, un chemin valide doit être renseigné"
  GoTo fin
errInc:
  MsgBox "FichierTXT: impossible de créer le fichier:" & vbNewLine & err.Description
  GoTo fin
End Sub

Public Sub ecrire(txt As String)
'ajoute une ligne au fichier
On Error GoTo err
  Print #locRef, txt
fin:
  Exit Sub
err:
  MsgBox "FichierTXT: impossible d'ajouter la ligne demandée:" & vbNewLine & err.Description
  GoTo fin
End Sub

Public Sub fermer()
On Error GoTo fin
  'on ferme le fichier s'il ne l'est pas déjà
  Close #locRef
fin:
End Sub

Private Sub class_Terminate()
On Error GoTo fin
  'on ferme le fichier s'il ne l'est pas déjà
  Close #locRef
fin:
End Sub